Add the function that return all key combinations for a possible key vector.

project.clj

@@ -7,7 +7,8 @@
                  [org.clojure/tools.cli "1.0.219"]
                  [org.apache.tika/tika-core "1.28.5"]
                  [org.apache.tika/tika-langdetect "1.28.5"]
-                 [cheshire "5.12.0"]]
+                 [cheshire "5.12.0"]
+                 [org.clojure/math.combinatorics "0.2.0"]]
   :main ^:skip-aot cipher-analytical-machine.core
   :java-source-paths ["src/main/java"]
   :target-path "target/%s"

src/cipher_analytical_machine/analyzers/analyzers.clj

@@ -11,6 +11,16 @@
             (inc (get acc val 0))))
    {} text))
 
+(defn reverse-count-characters
+  "Convert a map of pairs to a map where the characters grouped by the count and a count is the key."
+  [count-map]
+  (reduce
+   (fn [acc [symbol count]]
+     (->> (conj (get acc count []) symbol)
+          (into [])
+          (assoc acc count)))
+   {} count-map))
+
 (defn chi-squared-letter-statistic
   "To calculate the frequency distribution of a letter."
   [letter-count letter-frequence length-text]
@@ -36,3 +46,22 @@
             0
             letter-counts)))
 
+(defn sort-map-by-count
+  "Return a list of pairs from a map of pairs where a pair is a character and its count. The order is descending."
+  [count-map]
+  (->> count-map
+       (reduce (fn [acc [char count]] (conj acc [char count])) [])
+       (sort-by #(- (second %)))))
+
+(defn table-to-string
+  "Return the string from a frequency table."
+  [table]
+  (->> (map first table)
+       (apply str)))
+
+(defn symbol-frequency-table
+  "Return a table where pairs is a symbol from a cipher text and its value which is a symbol from frequency table."
+  [cipher-table frequency-table]
+  (zipmap (table-to-string (sort-map-by-count cipher-table))
+          (table-to-string (sort-map-by-count frequency-table))))
+

src/cipher_analytical_machine/analyzers/simple_substitution.clj

@@ -0,0 +1,44 @@
+(ns cipher-analytical-machine.analyzers.simple-substitution
+  (:require [clojure.string :as cs]
+            [clojure.math.combinatorics :as comb]
+            [cipher-analytical-machine.ciphers.simple-substitution :as ss]
+            [cipher-analytical-machine.analyzers.analyzers :as analyzers]
+            [cipher-analytical-machine.analyzers.caesar :as caesar])
+  (:gen-class))
+
+(defn get-possible-key-vector
+  "Convert a possible key map to a vector of possible keys. For example, if you have a map: {\\a [\\a \\b \\c] \\b [\\b \\c] \\c [\\a \\c]}, then the vector is [[\\a \\b \\c] [\\b \\c] [\\a \\c]]."
+  [possible-key-map symbols]
+  (reduce
+   (fn [acc el]
+     (conj acc (get possible-key-map el)))
+   [] symbols))
+
+(defn get-possible-key-vector-from-reversed-count-map
+  "Convert a reversed count map to a vector. Example, from {2 [\\a \\b] 1 [\\d] 3 [\\e]} to [[\\e] [\\a \\b] [\\d]])."
+  [reversed-count-map]
+  (->>  reversed-count-map
+        (into [])
+        (sort-by #(- (first %)))
+        (map second)
+        (into [])))
+
+(defn get-all-permutation-for-block
+  "Return a vector for all possible blocks that can be made from a vector of symbols."
+  [symbols]
+  (->> (comb/permutations symbols)
+       (map cs/join)
+       (into [])))
+
+(defn get-all-combinations-for-blocks
+  "Return the all combination of blocks in a possible key vector. For example, if you have a map: {\\a [\\a \"bf\" \\c] \\b [\"bf\" \\c] \\c [\\a \\c]}, then the vector is [[\\a \"bf\" \\c] [\"bf\" \\c] [\\a \\c]] and keys (\"abfa\" \"abfc\" ...)."
+  [possible-key-vector]
+  (->> (apply comb/cartesian-product possible-key-vector)
+       (map cs/join)))
+
+(defn get-possible-key-combinations
+  "Return possible keys for a possible key vector. For example, if you have a map: {\\a [\\a \\b \\c] \\e [\\f \\g] \\c [\\a \\c]}, then the keys are (\"abcefg\" \"abcegf\" ...)."
+  [possible-key-vector]
+  (->> (map get-all-permutation-for-block possible-key-vector)
+       (get-all-combinations-for-blocks)))
+

src/cipher_analytical_machine/ciphers/gamma.clj

@@ -0,0 +1,78 @@
+(ns cipher-analytical-machine.ciphers.gamma
+  (:require
+   [clojure.set :as set]
+   [clojure.string :as cs]
+   [cipher-analytical-machine.ciphers.simple-substitution :as ss])
+  (:gen-class))
+
+(defn add-mod
+  [f s module]
+  (-> (+ f s)
+      (mod module)))
+
+(defn generate-seq
+  "Generate a lazy sequence for a key (a b c)."
+  [a b c module]
+  ((fn build-seq [a b c]
+     (lazy-seq (cons a (build-seq b c (add-mod a c module))))) a b c))
+
+(defn generate-gamma-seq
+  "Generate the gamma seq from a sequence."
+  [acc seq module]
+  (if (= (second seq) nil) acc
+    (generate-gamma-seq
+     (conj acc (add-mod (first seq) (second seq) module))
+     (rest seq)
+     module)))
+
+(defn generate-gamma
+  "Generate the gamma from a key (a b c)."
+  [a b c module size]
+  (generate-gamma-seq []
+                      (->> (generate-seq a b c module)
+                           (take (inc size)))
+                      module))
+
+(defn encrypt-array
+  "Encrypt an array using the gamma cipher. The function is case-insensitive. The key is an array of three elements [a b c]. The array contains integer in range [0, module)."
+  [key module array]
+  (let [size (count array)
+        gamma (->> (apply conj [key module size])
+                   (apply generate-gamma))]
+    (->> gamma
+         (map vector array)
+         (map (fn [[a g]] (add-mod a g module))))))
+
+(defn encrypt-message
+  "Encrypt a message using the gamma cipher. The function is case-insensitive. The key is an array of three elements [a b c]. The array contains integer in range [0, module)."
+  [key symbols message]
+  (let [module (count symbols)
+        table (ss/generate-sorted-substitution-table symbols)]
+    (->> message
+         (ss/decrypt-by-table (set/map-invert table))
+         (encrypt-array key module)
+         (ss/decrypt-by-table table)
+         (cs/join))))
+
+(defn decrypt-array
+  "Decrypt an array using the gamma cipher. The function is case-insensitive. The key is an array of three elements [a b c]. The array contains integer in range [0, module)."
+  [key module array]
+  (let [size (count array)
+        gamma (->> (apply conj [key module size])
+                   (apply generate-gamma))]
+    (->> gamma
+         (map -)
+         (map vector array)
+         (map (fn [[a g]] (add-mod a g module))))))
+
+(defn decrypt-message
+  "Decrypt a message using the gamma cipher. The function is case-insensitive. The key is an array of three elements [a b c]. The array contains integer in range [0, module)."
+  [key symbols message]
+  (let [module (count symbols)
+        table (ss/generate-sorted-substitution-table symbols)]
+    (->> message
+         (ss/decrypt-by-table (set/map-invert table))
+         (decrypt-array key module)
+         (ss/decrypt-by-table table)
+         (cs/join))))
+

src/cipher_analytical_machine/ciphers/simple_substitution.clj

@@ -29,11 +29,16 @@
   [char substitution-table]
   (get substitution-table char))
 
+(defn decrypt-by-table
+  "Decrypt a message by the substitution-table"
+  [substitution-table message]
+  (map (fn [char] (find-value-in-table char substitution-table)) message))
+
 (defn encrypt-message
   "Encrypt a message using the simple substitution cipher. The function is case-insensitive. If a symbol isn't in the symbols list, then it will be removed."
   [message substitution-table]
   (->> message
-       (map (fn [char] (find-value-in-table char substitution-table)))
+       (decrypt-by-table substitution-table)
        (remove nil?)
        (cs/join \,)))
 
@@ -44,15 +49,21 @@
       (caesar/encrypt-message key symbols)
       (encrypt-message substitution-table)))
 
+(defn decrypt-message-by-symbol-table
+  "Decrypt a message using the simple substitution cipher. The function is case-insensitive. The substitution-table must be (symbols, symbols)."
+  [substitution-table message]
+  (->> message
+       (decrypt-by-table substitution-table)
+       (remove nil?)
+       (cs/join)))
+
 (defn decrypt-message
-  "Decrypt a message using the simple substitution cipher. The function is case-insensitive. The substitution-table must be "
+  "Decrypt a message using the simple substitution cipher. The function is case-insensitive. The substitution-table must be (int, symbols)."
   [message substitution-table]
   (let [message (cs/split message #",")]
     (->> message
          (map #(Integer/parseInt %))
-         (map (fn [char] (find-value-in-table char substitution-table)))
-         (remove nil?)
-         (cs/join))))
+         (decrypt-message-by-symbol-table substitution-table))))
 
 (defn decrypt-message-with-caesar
   "Decrypt a message using the simple substitution cipher and the Caesar cipher. The function is case-insensitive."

src/cipher_analytical_machine/cli/actions/cracking.clj

@@ -9,7 +9,8 @@
   (let [analyzer (:analyzer options)
         message (:message options)
         symbols (:symbols options)
-        frequencies symbol-frequencies/english-letter-frequencies]
+        frequencies (-> (get options :language "en")
+                        (symbol-frequencies/default-frequency-factory))]
     (cond
       (= analyzer "Chi^2")
       (caesar-analyzers/get-plaintext message symbols frequencies)

src/cipher_analytical_machine/cli/actions/cryptography.clj

@@ -1,6 +1,11 @@
 (ns cipher-analytical-machine.cli.actions.cryptography
   (:require
-   [cipher-analytical-machine.ciphers.caesar :as caesar])
+   [clojure.string :as cs]
+   [cipher-analytical-machine.ciphers.caesar :as caesar]
+   [cipher-analytical-machine.ciphers.simple-substitution :as ss]
+   [cipher-analytical-machine.ciphers.gamma :as gamma]
+   [cipher-analytical-machine.parsers.parsers :as ps]
+   [cipher-analytical-machine.parsers.simple-substitution :as pss])
   (:gen-class))
 
 (defn caesar-actions
@@ -15,10 +20,50 @@
       (= action-type :decrypt)
       (caesar/decrypt-message message key symbols))))
 
+(defn simple-substitution-with-caesar-actions
+  [options arguments action-type]
+  (let [message (:message options)
+        key (:key options)
+        symbols (:symbols options)]
+    (cond
+      (= action-type :encrypt)
+      (let [data (pss/generate-table-or-decode-json key symbols)
+            key (ps/parse-unsigned-int (get data "key"))
+            substitution-table (get data "table")]
+        (println (pss/encode-key-and-substitution-table-to-json key substitution-table))
+        (ss/encrypt-message-with-caesar message key substitution-table symbols))
+
+      (= action-type :decrypt)
+      (let [data (-> (pss/decode-key-and-substitution-table-from-json key)
+                     (pss/invert-table-in-map))
+            key (get data "key")
+            substitution-table (get data "table")]
+        (ss/decrypt-message-with-caesar message key substitution-table symbols)))))
+
+(defn gamma-actions
+  [options arguments action-type]
+  (let [message (:message options)
+        key (->> (cs/split (:key options) #",")
+                 (map #(Integer/parseInt %))
+                 (into []))
+        symbols (:symbols options)]
+    (cond
+      (= action-type :encrypt)
+      (gamma/encrypt-message key symbols message)
+
+      (= action-type :decrypt)
+      (gamma/decrypt-message key symbols message))))
+
 (defn cryptography-actions
   [options arguments action-type]
   (let [cipher (:cipher options)]
     (cond
       (= cipher "Caesar")
-      (caesar-actions options arguments action-type))))
+      (caesar-actions options arguments action-type)
+
+      (= cipher "Simple substitution and Caesar")
+      (simple-substitution-with-caesar-actions options arguments action-type)
+
+      (= cipher "Gamma")
+      (gamma-actions options arguments action-type))))
 

src/cipher_analytical_machine/cli/cli.clj

@@ -1,5 +1,7 @@
 (ns cipher-analytical-machine.cli.cli
   (:require
+   [cipher-analytical-machine.parsers.parsers :as ps]
+   [cipher-analytical-machine.parsers.gamma :as gamma-ps]
    [cipher-analytical-machine.cli.file :as file]
    [cipher-analytical-machine.symbols.factories :as sf]
    [cipher-analytical-machine.cli.options :as options]
@@ -77,6 +79,15 @@
            (or (contains? options :encrypt)
                (contains? options :decrypt)))
       (cond
+        (and (= (:cipher options) "Caesar")
+             (false? (ps/int-string? (:key options))))
+        {:exit-message (error-msg ["Please, use the key format: [+-](integer)!!! Example: 10, +9, -7."])}
+
+        (and (= (:cipher options) "Gamma")
+             (false? (gamma-ps/key? (:key options))))
+        {:exit-message (error-msg ["Please, use the key format: [+-](integer),[+-](integer),[+-](integer) !!! Example: 10,+9,-7."])}
+
+
         (contains? options :encrypt)
         {:options options :arguments arguments :action-type :encrypt}
 
@@ -160,3 +171,10 @@
 
      (show-and-save-output options))))
 
+(defn cli-main
+  [args]
+  (let [{:keys [options arguments action-type exit-message ok?]} (validate-args args)]
+    (if exit-message
+      (exit exit-message ok?)
+      (actions options arguments action-type))))
+

src/cipher_analytical_machine/cli/options.clj

@@ -22,7 +22,7 @@
     (option-values-as-list option values)))
 
 (def cipher-options
-  #{"Caesar"})
+  #{"Caesar" "Simple substitution and Caesar" "Gamma"})
 
 (def default-cipher "Caesar")
 

src/cipher_analytical_machine/core.clj

@@ -5,8 +5,5 @@
 
 (defn -main
   [& args]
-  (let [{:keys [options arguments action-type exit-message ok?]} (cli/validate-args args)]
-    (if exit-message
-      (cli/exit exit-message ok?)
-      (cli/actions options arguments action-type))))
+  (cli/cli-main args))
 

src/cipher_analytical_machine/parsers/gamma.clj

@@ -0,0 +1,9 @@
+(ns cipher-analytical-machine.parsers.gamma
+  (:gen-class))
+
+(defn key?
+  "Return true if the string is an key of three integers."
+  [str]
+  (if (re-matches #"[+-]?\b\d+\b,[+-]?\b\d+\b,[+-]?\b\d+\b" str)
+    true false))
+

src/cipher_analytical_machine/parsers/parsers.clj

@@ -2,8 +2,28 @@
   (:require [cheshire.core :as cc])
   (:gen-class))
 
-(defn unsigned-int?
+(defn unsigned-int-string?
+  "Return true if the string is an unsigned integer."
   [str]
   (if (re-matches #"\d+" str)
     true false))
 
+(defn int-string?
+  "Return true if the string is an signed integer."
+  [str]
+  (if (re-matches #"[+-]?\b\d+\b" str)
+    true false))
+
+(defn parse-unsigned-int
+  "Return an integer if the argument is an integer."
+  [str-or-int]
+  (cond
+    (int? str-or-int)
+    str-or-int
+
+    (unsigned-int-string? str-or-int)
+    (Integer/parseInt str-or-int)
+
+    :else
+    nil))
+

src/cipher_analytical_machine/parsers/simple_substitution.clj

@@ -2,6 +2,7 @@
   (:require
    [cipher-analytical-machine.ciphers.simple-substitution :as ss]
    [cipher-analytical-machine.parsers.parsers :as ps]
+   [clojure.set :as set]
    [cheshire.core :as cc])
   (:gen-class))
 
@@ -14,14 +15,14 @@
 (defn decode-key
   "Returns the first character if the string is a char. Return the number if the string is a number."
   [str]
-  (if (ps/unsigned-int? str)
+  (if (ps/unsigned-int-string? str)
     (Integer/parseInt str)
     (first str)))
 
 (defn decode-pair
   "Decode a numbers as a string and a char as a string"
   [acc [key value]]
-  (if (ps/unsigned-int? key)
+  (if (ps/unsigned-int-string? key)
     (assoc acc (decode-key key) (decode-key value))
     (assoc acc (decode-key key) value)))
 
@@ -37,8 +38,17 @@
 (defn generate-table-or-decode-json
   "It generate the table and return map with the key and the table if the argument is a key. Else it decode the json."
   [key-or-json symbols]
-  (if (ps/unsigned-int? key-or-json)
+  (if (ps/unsigned-int-string? key-or-json)
     (-> {"key" key-or-json}
         (assoc "table" (ss/generate-substitution-table symbols)))
     (decode-key-and-substitution-table-from-json key-or-json)))
 
+(defn invert-table-in-map
+  "Invert the table in a decoded json (key, table)"
+  [decoded-json]
+  (->>
+   (-> decoded-json
+       (get "table")
+       (set/map-invert))
+   (assoc decoded-json "table")))
+

src/cipher_analytical_machine/symbols/frequencies.clj

@@ -77,3 +77,16 @@
    \  0.138
 })
 
+(defn default-frequency-factory
+  "Returns a default map of letter frequencies for a language"
+  [language-code]
+  (cond
+    (= language-code "en")
+    english-letter-frequencies
+
+    (= language-code "uk")
+    ukrainian-letter-frequencies
+
+    :else
+    english-letter-frequencies))
+

test/cipher_analytical_machine/analyzers/analyzers_test.clj

@@ -0,0 +1,47 @@
+(ns cipher-analytical-machine.analyzers.analyzers-test
+  (:require
+   [clojure.test :refer :all]
+   [cipher-analytical-machine.analyzers.analyzers :refer :all]))
+
+(deftest count-characters-test
+  (testing "Count two dublicates and one uniq character from a string."
+    (is (= {\a 2 \b 1}
+           (count-characters "aba")))))
+
+(deftest reverse-count-characters-test
+  (testing "The symbols must be grouped as a vector and the count must be a key."
+    (are [count-map expected-map]
+        (= expected-map (reverse-count-characters count-map))
+      {\a 1 \b 2 \c 1} {1 [\a \c] 2 [\b]}
+      {\a 1 \b 2 \c 3} {1 [\a] 2 [\b] 3 [\c]})))
+
+(deftest chi-squared-letter-statistic-test
+  (testing "If the frequence of A is 0.1, the text length is 100 and contains 20 times, then the chi-squared is 10."
+    (is (= 10.0
+           (chi-squared-letter-statistic 20 0.1 100))))
+
+  (testing "If the frequence of A is 0.1, the text length is 10 and contains 5 times, then the chi-squared is 16.0."
+    (is (= 16.0
+           (chi-squared-letter-statistic 5 0.1 10)))))
+
+(deftest chi-squared-statistic-test
+  (let [text "aaaaabbbbb"]
+  (testing "If the frequencies of a and b is 0.1, the text length is 10 and contains them 5 times, then score is 32."
+    (is (= 32.0
+           (chi-squared-statistic text {\a 0.1 \b 0.1}))))))
+
+(deftest sort-map-by-count-test
+  (testing "Test the sort in descending order."
+    (is (= [[\b 3] [\a 2] [\c 1]]
+           (sort-map-by-count {\a 2 \b 3 \c 1} )))))
+
+(deftest table-to-string-test
+  (testing "Test the sort in descending order."
+    (is (= "bac"
+           (table-to-string [[\b 3] [\a 2] [\c 1]])))))
+
+(deftest symbol-frequency-table-test
+  (testing "Test the sort in descending order."
+    (is (= {\d \b, \e \a, \f \c}
+           (symbol-frequency-table {\d 3 \e 2 \f 1} {\b 3 \a 2 \c 1})))))
+

test/cipher_analytical_machine/analyzers/simple_substitution_test.clj

@@ -0,0 +1,50 @@
+(ns cipher-analytical-machine.analyzers.simple-substitution-test
+  (:require
+   [clojure.test :refer :all]
+   [cipher-analytical-machine.symbols.frequencies :as sf]
+   [cipher-analytical-machine.ciphers.simple-substitution :as ss]
+   [cipher-analytical-machine.analyzers.simple-substitution :refer :all])
+  (:gen-class))
+
+(deftest get-possible-keys-vector-test
+  (testing "The vector must be ordered by symbols"
+    (are [possible-keys-map symbols expected-key-vector]
+        (= expected-key-vector (get-possible-key-vector possible-keys-map symbols))
+      {\a [\a \b] \b [\b \a] \c [\a \c]} "abc" [[\a \b] [\b \a] [\a \c]]
+      {\a [\a \b] \c [\b \a] \b [\a \c]} "abc" [[\a \b] [\a \c] [\b \a]])))
+
+(deftest get-possible-key-vector-from-reversed-count-map-test
+  (testing "The block order must be in descending order"
+    (are [reversed-count-map expected-key-vector]
+        (= expected-key-vector (get-possible-key-vector-from-reversed-count-map reversed-count-map))
+      {1 [\a \c] 2 [\b]}     [[\b] [\a \c]]
+      {2 [\a] 1 [\b] 3 [\c]} [[\c] [\a] [\b]])))
+
+(deftest get-all-permutation-for-block-test
+  (testing "It must return all permutations"
+    (are [symbols expected-permutations]
+        (= expected-permutations (get-all-permutation-for-block symbols))
+      [\a \b]    ["ab" "ba"]
+      [\a \b \c] ["abc" "acb" "bac" "bca" "cab" "cba"])))
+
+(deftest get-all-combinations-for-blocks-test
+  (testing "The keys must be the all combinations of blocks"
+    (are [possible-keys-vector expected-keys]
+        (= expected-keys (get-all-combinations-for-blocks possible-keys-vector))
+      [[\a \b] [\f] [\a \c] [\g]] '("afag" "afcg" "bfag" "bfcg")
+      [[\a \b] [\a \c]] '("aa" "ac" "ba" "bc")
+      [[\a \b \c] [\a \c] [\b \c]] '("aab" "aac" "acb" "acc" "bab" "bac" "bcb" "bcc" "cab" "cac" "ccb" "ccc"))))
+
+(deftest get-possible-key-combinations-test
+  (testing "The keys must be the all combinations, but the blocks must create a permutations which will be joined as a combination"
+    (are [possible-keys-vector expected-keys]
+        (= expected-keys (get-possible-key-combinations possible-keys-vector))
+      [[\a \b] [\f] [\e \c] [\g]] '("abfecg" "abfceg" "bafecg" "bafceg")
+      [[\a \b] [\a \c]] '("abac" "abca" "baac" "baca")
+      [[\a \b \c] [\a \c] [\b \c]] '("abcacbc" "abcaccb" "abccabc" "abccacb"
+                                     "acbacbc" "acbaccb" "acbcabc" "acbcacb"
+                                     "bacacbc" "bacaccb" "baccabc" "baccacb"
+                                     "bcaacbc" "bcaaccb" "bcacabc" "bcacacb"
+                                     "cabacbc" "cabaccb" "cabcabc" "cabcacb"
+                                     "cbaacbc" "cbaaccb" "cbacabc" "cbacacb"))))
+

test/cipher_analytical_machine/ciphers/gamma_test.clj

@@ -0,0 +1,62 @@
+(ns cipher-analytical-machine.ciphers.gamma-test
+  (:require
+   [clojure.test :refer :all]
+   [cipher-analytical-machine.ciphers.gamma :refer :all]))
+
+(deftest add-mod-test
+  (testing "The remainder must be as expected."
+    (are [a b module expected]
+        (= expected (add-mod a b module))
+      5 2 4 3
+      1 2 3 0
+      2 2 3 1)))
+
+(deftest generate-seq-test
+  (testing "Checking that the next element of a sequence is calculated by (e[i-1] + e[i-3] % mod)."
+    (are [a b c module size expected]
+        (= expected (take size (generate-seq a b c module)))
+      4 32 15 33 10 [4 32 15 19 18 0 19 4 4 23]
+      1 2  3  3  9  [1 2 3 1 0 0 1 1 1])))
+
+(deftest generate-gamma-seq-test
+  (testing "Checking that the next element of a sequence is calculated by (s[i] + s[i+1] % mod)."
+    (are [acc seq module expected]
+        (= expected (generate-gamma-seq acc seq module))
+      [] [4 32 15 19 18 0 19 4 4 23] 33 [3 14 1 4 18 19 23 8 27]
+      [] [1 2 3 1 0 0 1 1 1]         3  [0 2 1 1 0 1 2 2])))
+
+(deftest generate-gamma-test
+  (testing "Checking that the gamma is generated as expected."
+    (are [a b c module size expected]
+        (= expected (generate-gamma a b c module size))
+      4 32 15 33 10 [3 14 1 4 18 19 23 8 27 17]
+      1 2  3  3  9  [0 2 1 1 0 1 2 2 0])))
+
+(deftest encrypt-array-test
+  (testing "Checking that the message is encrypted as expected: (msg+gamma)%module."
+    (are [key module array expected]
+        (= expected (encrypt-array key module array))
+      [4 32 15] 33 [3 14 1 4 18 19 23 8 27 17] [6 28 2 8 3 5 13 16 21 1]
+      [1 2  3 ] 3  [0 2 1 1 0 1 2 2 0]         [0 1 2 2 0 2 1 1 0])))
+
+(deftest encrypt-message-test
+  (testing "Checking that the message is encrypted as expected"
+    (are [key symbols message expected]
+        (= expected (encrypt-message key symbols message))
+      [4 32 15] "абвгґдеєжзиіїйклмнопрстуфхцчшщьюя" "гкбґопужчн" "ешвжгдймсб"
+      [1 2  3 ] "абв"  "авббабвва"  "абввавбба")))
+
+(deftest decrypt-array-test
+  (testing "Checking that the message is decrypted as expected."
+    (are [key module array expected]
+        (= expected (decrypt-array key module array))
+      [4 32 15] 33 [6 28 2 8 3 5 13 16 21 1] [3 14 1 4 18 19 23 8 27 17]
+      [1 2  3 ] 3  [0 1 2 2 0 2 1 1 0]       [0 2 1 1 0 1 2 2 0])))
+
+(deftest decrypt-message-test
+  (testing "Checking that the message is decrypted as expected"
+    (are [key symbols message expected]
+        (= expected (decrypt-message key symbols message))
+      [4 32 15] "абвгґдеєжзиіїйклмнопрстуфхцчшщьюя" "ешвжгдймсб" "гкбґопужчн"
+      [1 2  3 ] "абв" "абввавбба" "авббабвва")))
+

test/cipher_analytical_machine/ciphers/simple_substitution_test.clj

@@ -48,6 +48,23 @@
         "abc" 1 "2,3,1"
         "aDbdc" 0 "1,2,3"))))
 
+(deftest decrypt-by-table-test
+  (let [table {\d \a \e \b \f \c}]
+    (testing "The function must decrypt the message by the table."
+      (are [message expected]
+          (= expected (decrypt-by-table table message))
+        "def" '(\a \b \c)
+        "abf" '(nil nil \c)
+        "fed" '(\c \b \a)))))
+
+(deftest decrypt-message-by-symbol-table-test
+  (let [table {\d \a \e \b \f \c}]
+    (testing "The function must decrypt the message and remove unknown numbers."
+      (are [message expected]
+          (= expected (decrypt-message-by-symbol-table table message))
+        "def" "abc"
+        "daef" "abc"))))
+
 (deftest decrypt-message-test
   (let [table {1 \a 2 \b 3 \c}]
     (testing "The function must decrypt the message and remove unknown numbers."

test/cipher_analytical_machine/parsers/gamma_test.clj

@@ -0,0 +1,20 @@
+(ns cipher-analytical-machine.parsers.gamma-test
+  (:require
+   [clojure.test :refer :all]
+   [cipher-analytical-machine.parsers.gamma :refer :all]))
+
+(deftest key?-test
+  (testing "The function return true only if the key in the format '%d,%d,%d'."
+    (are [str expected]
+        (= expected
+           (key? str))
+      "9"         false
+      "9,10"      false
+      "10,9,8"    true
+      "-10,9,-8"  true
+      "-10,-9,-8" true
+      "asd 10 "   false
+      " 10 "      false
+      "-10"       false
+      "abc"       false)))
+

test/cipher_analytical_machine/parsers/parsers_test.clj

@@ -3,13 +3,38 @@
    [clojure.test :refer :all]
    [cipher-analytical-machine.parsers.parsers :refer :all]))
 
-(deftest unsigned-int?-test
-  (testing ""
+(deftest unsigned-int-string?-test
+  (testing "The function return true only for an unsingned integer as a string."
     (are [str expected]
         (= expected
-           (unsigned-int? str))
+           (unsigned-int-string? str))
+      "9" true
       "9" true
       "10" true
+      "asd 10 " false
+      " 10 " false
       "-10" false
       "abc" false)))
 
+(deftest int-string?-test
+  (testing "The function return true only for an singned integer as a string."
+    (are [str expected]
+        (= expected
+           (int-string? str))
+      "9" true
+      "10" true
+      "-10" true
+      "asd -10 " false
+      " -10 " false
+      "abc" false)))
+
+(deftest parse-unsigned-int-test
+  (testing "The function parse the integer if the string is an integer."
+    (are [str-or-int expected]
+        (= expected
+           (parse-unsigned-int str-or-int))
+      "9"   9
+      9     9
+      "10"  10
+      "-10" nil
+      "abc" nil)))

test/cipher_analytical_machine/parsers/simple_substitution_test.clj

@@ -39,3 +39,11 @@
         "1" {"key" 1 "table" {0 \a 1 \b 2 \c}}
         "2" {"key" 2 "table" {\a 0 \b 1 \c 2}}))))
 
+(deftest invert-table-in-map-test
+  (testing "The function invert the table in a decoded json."
+    (are [decoded-json expected-data]
+        (= expected-data
+           (invert-table-in-map decoded-json))
+      {"key" 1 "table" {0 \a 1 \b 2 \c}} {"key" 1 "table" {\a 0 \b 1 \c 2}}
+      {"key" 2 "table" {\a 0 \b 1 \c 2}} {"key" 2 "table" {0 \a 1 \b 2 \c}})))
+

test/cipher_analytical_machine/symbols/frequencies_test.clj

@@ -9,3 +9,13 @@
       (is (= "etaoinsrhldcumfpgwybvkxjqz"
              (map-to-string symbol-map))))))
 
+(deftest default-frequency-factory-test
+  (testing "Factory supports languages: English (en), Ukrainian (uk). If language code is unidentified, then it must have the 'en'."
+    (are [language-code expected-map-size]
+        (->> (default-frequency-factory language-code)
+             count
+             (= expected-map-size))
+      "en"           26
+      "uk"           34
+      "Maybe a code" 26)))
+